blob: 701a42ad0c19a0de8049e1716a47074f1f4c548d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
_pkgname=compcodeR
_pkgver=1.42.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="RNAseq data simulation, differential expression analysis and performance comparison of differential expression methods"
arch=(any)
url="https://bioconductor.org/packages/$_pkgname"
license=('GPL-2.0-or-later')
depends=(
r-ape
r-catools
r-edger
r-ggplot2
r-gplots
r-gtools
r-knitr
r-limma
r-markdown
r-matrixstats
r-modeest
r-phylolm
r-rmarkdown
r-rocr
r-shiny
r-shinydashboard
r-sm
r-stringr
r-vioplot
)
checkdepends=(
r-ggtree
r-phangorn
r-phytools
r-testthat
r-tidytree
)
optdepends=(
r-biocstyle
r-covr
r-deseq2
r-ebseq
r-genefilter
r-ggtree
r-nbpseq
r-noiseq
r-phangorn
r-phytools
r-statmod
r-sva
r-tcc
r-testthat
r-tidytree
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('ecec021bb3b146653a2ccd867faaa0b7')
b2sums=('fd680644b9534b3ecbb771e61274a6622b376488d174fed47f67cf17e5ceab8190b9133cab6f2523c2d9107ff491fcde78578a38239c6c5bc18853b546faa1c9')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|