blob: cc3c27b4211a472fbef26c44792c8192b3916694 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: sukanka <su975853527@gmail.com>
_pkgname=pema
_pkgver=0.1.3
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=5
pkgdesc="Penalized Meta-Analysis"
arch=(x86_64)
url="https://cran.r-project.org/package=$_pkgname"
license=('GPL-3.0-or-later')
depends=(
onetbb
r-ggplot2
r-rcpp
r-rcppparallel
r-rstan
r-rstantools
r-shiny
r-sn
)
makedepends=(
r-bh
r-rcppeigen
r-stanheaders
)
checkdepends=(
r-mice
r-testthat
)
optdepends=(
r-knitr
r-mice
r-rmarkdown
r-testthat
)
source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('d1fa3f8e2a111ba6676879539a07780a')
b2sums=('f03d675e965efd177fe3781f7d42b8966e2a998713f807091bde887fc390cf0b72e96d32138be134e469f1c2c51e735dd0001934265e449e9ad5188cb3b342a9')
build() {
mkdir build
# compilation needs a lot of memory
MAKEFLAGS+=" -j1"
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|