1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: peippo <christoph+aur@christophfink.com>
_cranname=terra
_cranver=1.7-83
pkgname=r-${_cranname,,}
pkgdesc="Spatial Data Analysis"
url="https://cran.r-project.org/package=${_cranname}"
license=("GPL3")
pkgver=${_cranver//[:-]/.}
pkgrel=1
arch=("i686" "x86_64")
depends=(
"gdal>=2.2.3"
"geos>=3.4.0"
"proj>=4.9.3"
"r-rcpp>=1.0.10"
"r>=3.5.0"
"sqlite"
)
optdepends=(
"r-deldir"
"r-htmlwidgets"
"r-leaflet>=2.2.1"
"r-ncdf4"
"r-sf>=0.9.8"
"r-tinytest"
"r-xml"
)
# The unittests for `r-terra` have multiple circular
# dependency chains.
# As such, the tests can not be run on first build.
# While R packages from CRAN, generally, are well-tested
# before they are released, in some situations, you want to
# have thorough testing on your own end.
# To run the tests, first build this package without `check()`
# (i.e., as-is) to bootstrap `r-terra`. Then, on subsequent builds,
# (assumining you have a local repository that is accessible from
# the build chroot), uncomment the lines defining `checkdepends`, below,
# as well as the `check()` function further down
# checkdepends=(
# "${optdepends[@]}"
# "r-rcmdcheck"
# )
source=("https://cran.r-project.org/src/contrib/${_cranname}_${_cranver}.tar.gz")
b2sums=("e8c248adbd68a6be78bc77af7ec4e7f0bfb3e7614a569bba1224295429d68e650587f2b8ea275286db30b6be6237758310171ddb6774789ab58474c9f0dc8ecc")
build() {
mkdir -p "${srcdir}/build/"
R CMD INSTALL ${_cranname}_${_cranver}.tar.gz -l "${srcdir}/build/"
}
# check() {
# export R_LIBS="build/"
# R CMD check --no-manual "${_cranname}"
# }
package() {
install -dm0755 "${pkgdir}/usr/lib/R/library"
cp -a --no-preserve=ownership "${srcdir}/build/${_cranname}" "${pkgdir}/usr/lib/R/library"
if [[ -f "${_cranname}/LICENSE" ]]; then
install -Dm0644 "${_cranname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
fi
}
|