PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Maintainer: Laura Demkowicz-Duffy <dev at demkowiczduffy.co.uk>
# Contributor: Michael Bauer <michael@m-bauer.org>
pkgname=radicle-cli
pkgver=1.1.0
pkgrel=1
pkgdesc="Radicle command line interface"
arch=('x86_64')
url="https://radicle/xyz"
license=('MIT' 'Apache-2.0')
depends=('libusb' 'gcc-libs' 'openssh' 'git' 'glibc' 'zlib')
makedepends=('cargo' 'git')

_man_pages="rad-id rad-patch rad git-remote-rad radicle-node"
 
_pkgver_commit=70f0cc35
_repoid=z3gqcJUoA1n9HaHKufZs5FCSGazv5

source=("heartwood-$pkgver::git+https://seed.radicle.xyz/$_repoid.git#commit=$_pkgver_commit")

sha512sums=('9e291eb0aae3013e63612d5847701d39eada352bf5cf48bc3e56ac098d29cf5f61ebe1cc20070493a7ded87a26edb6fb17ad31ea899dafaae5603835d08d8aad')

prepare() {
	cd "$srcdir/heartwood-$pkgver"
	cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}

build() {
	cd "$srcdir/heartwood-$pkgver"
	export CARGO_TARGET_DIR=target
	cargo build --frozen --release --all-features

	for page in $_man_pages; do
		bash scripts/build-man-pages.sh target "$page.1.adoc"
	done
}

check() {
	cd "$srcdir/heartwood-$pkgver"
	cargo test --frozen --all-features
}

package() {
	cd "$srcdir/heartwood-$pkgver"
	find target/release \
		-maxdepth 1 \
		-executable \
		-type f \
		-exec install -Dm0755 -t "$pkgdir/usr/bin/" {} +

	for page in $_man_pages; do
		install -Dm0644 "target/$page.1" "$pkgdir/usr/share/man/man1/$page.1"
	done

	install -Dm0644 LICENSE-MIT "$pkgdir/usr/share/licenses/$pkgname/LICENSE-MIT"
	install -Dm0644 LICENSE-APACHE "$pkgdir/usr/share/licenses/$pkgname/LICENSE-APACHE"

	install -Dm0644 systemd/radicle-node.service "$pkgdir/usr/lib/systemd/user/radicle-node.service"
}