summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 899db3929672e1576aaa276fe76ad653a1885250 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# Maintainer: Dwi Mulia Mokoginta <dwi-mulia-mokoginta@protonmail.com>
# Contributor: dreamscached <dreamscache.d@gmail.com>

_pkgname="recaf"
pkgname="$_pkgname"
pkgver=2.21.14
pkgrel=2
pkgdesc="A modern Java bytecode editor"
url="https://github.com/Col-E/Recaf"
license=('MIT')

arch=("any")
depends=('java-environment-openjdk=24' "ttf-font")
makedepends=('jdk24-openjdk')

conflicts=("$_pkgname-bin" "$_pkgname-git")
replaces=("$_pkgname")
provides=("$_pkgname" "$_pkgname-git")

source=(
    "$_pkgname-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz"
    "LICENSE::https://raw.githubusercontent.com/Col-E/Recaf/$pkgver/LICENSE"
    "$_pkgname"
    "$_pkgname.desktop"
)

build() {
  cd "Recaf-$pkgver"

  JAVA_HOME="/usr/lib/jvm/default-runtime" ./mvnw clean package -Dmaven.test.skip -Dcheckstyle.skip
}

sha256sums=(
    'ae0a25f167f331aab374db74021c5ef162b3fb38768c369ae06e8b8242f01f7e'
    'a13cb1a246bc0986c7185510a7ea9880e9f8eaf6d3a0437e2f3f2e2e85e9abb5'
    'SKIP'
    'SKIP'
)

package() {
    cd "Recaf-$pkgver"

    sed -i "/^Version=/c\Version=$pkgver" "$srcdir/$_pkgname.desktop"
    sed -i "/^Comment=/c\Comment=$pkgdesc" "$srcdir/$_pkgname.desktop"

    install -Dm755 "target/$_pkgname-$pkgver-J8-jar-with-dependencies.jar" "$pkgdir/usr/share/java/$_pkgname/$_pkgname.jar"
    install -Dm755 "$srcdir/$_pkgname" "$pkgdir/usr/bin/recaf"
    install -Dm644 "$srcdir/$_pkgname.desktop" "$pkgdir/usr/share/applications/$_pkgname.desktop"

    install -Dm644 "src/main/resources/icons/logo-full.png" "$pkgdir/usr/share/pixmaps/$_pkgname.png"
    
    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
}