blob: a777bbdeccfd52f79f21e2853555e4cb48a95c3b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Mike Swanson <mikeonthecomputer@gmail.com>
pkgname=reposurgeon
pkgver=5.3
pkgrel=1
pkgdesc="Performs surgery on version control repositories."
arch=('x86_64')
url="http://www.catb.org/esr/$pkgname/"
license=('BSD')
makedepends=('asciidoctor' 'go' 'git' 'xmlto')
optdepends=('bitkeeper'
'bzr'
'cvs-fast-export'
'darcs'
'fossil'
'git'
'mercurial'
'sccs'
'src'
'subversion')
source=("https://gitlab.com/esr/$pkgname/-/archive/$pkgver/$pkgname-$pkgver.tar.gz")
b2sums=('330b2ec07a45ea32bcb1bfec01b73f7ecea7d1367d0c95d99b8f99ddcb979a70f06be6e79d3c9dfe50c59bec2488993436035a7cfe5cfe4714a766ff4ac9c4f1')
prepare() {
cd "$pkgbase-$pkgver"
for patch in ../*.patch; do
if [ ! -f "$patch" ]; then
break;
else
patch -p1 -i "$patch"
fi
done
}
build() {
cd "$pkgbase-$pkgver"
# Use -j1 so reposurgeon always gets built before options.adoc is needed
if [ "$(go version | grep gccgo)" ]; then
make GOFLAGS="" -j1
else
make -j1
fi
}
check() {
cd "$pkgbase-$pkgver"
make test
}
package_reposurgeon() {
cd "$pkgbase-$pkgver"
if [ "$(go version | grep gccgo)" ]; then
make GOFLAGS="" DESTDIR="$pkgdir" prefix=/usr install
else
make DESTDIR="$pkgdir" prefix=/usr install
fi
install -dm755 "$pkgdir/usr/share/emacs/site-lisp"
install -Dm644 reposurgeon-mode.el "$pkgdir/usr/share/emacs/site-lisp"
install -Dm644 COPYING "$pkgdir/usr/share/licenses/reposurgeon/COPYING"
}
|