PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer: bemxio <bemxiov at protonmail dot com>

pkgname="resource-hacker"
pkgdesc="A resource editor for 32/64-bit Windows applications"

pkgver=5.2.7
pkgrel=3

arch=(any)

url="http://www.angusj.com/resourcehacker"
license=("LicenseRef-ResourceHacker")

depends=(wine)
makedepends=(gendesk icoutils)

provides=(resource-hacker)

source=("http://www.angusj.com/resourcehacker/resource_hacker.zip" "resource-hacker" "LICENSE")
md5sums=("b1f79f26558459d1b401ba9ece2e8d66" "d22c27bfeda3b660598ab6c918728d55" "f686b88c5279285dfa50e4e5a54a538c")

prepare() {
	# extract the icon out of the executable
	wrestool -x -n MAINICON ResourceHacker.exe -o ResourceHacker.ico

	# get the highest quality PNG from the icon file
	icotool -x ResourceHacker.ico -i 1 -o ResourceHacker.png

	# generate a .desktop file
	gendesk -f -n \
		--pkgname "Resource Hacker" \
		--pkgdesc "${pkgdesc}" \
		--exec resource-hacker \
		--icon resource-hacker.png \
		--categories "Development;Utility"
}

package() {
	# copy all of Resource Hacker's files
	install -Dm755 ResourceHacker.exe "${pkgdir}/usr/share/resource-hacker/ResourceHacker.exe"

	install -Dm644 ReadMe.txt "${pkgdir}/usr/share/resource-hacker/ReadMe.txt"
	install -Dm644 changes.txt "${pkgdir}/usr/share/resource-hacker/changes.txt"

	find help -type f -exec install -Dm644 {} "${pkgdir}/usr/share/resource-hacker/{}" \;
	find samples -type f -exec install -Dm644 {} "${pkgdir}/usr/share/resource-hacker/{}" \;

	# copy the executable script
	install -Dm755 resource-hacker "${pkgdir}/usr/bin/resource-hacker"

	# copy the extracted icon and the generated .desktop file
	install -Dm644 ResourceHacker.png "${pkgdir}/usr/share/pixmaps/resource-hacker.png"
	install -Dm644 "Resource Hacker.desktop" "${pkgdir}/usr/share/applications/resource-hacker.desktop"

	# copy the license file
	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}