blob: c6b5736697bb9ed91237dfcb7810621ef61a55ec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Jianfeng Zhang <swordfeng123@gmail.com>
pkgname=ringo
pkgver=1.2.1
pkgrel=2
pkgdesc="Multi-threaded JavaScript on the JVM"
arch=('any')
url="https://ringojs.org/"
license=('Apache')
depends=('java-runtime-headless' 'bash')
makedepends=('ant' 'ivy' 'patch')
source=("git+https://github.com/ringo/ringojs.git#tag=v${pkgver}"
'patch.diff')
sha256sums=('SKIP'
'924efdfe4c4f71c36578759edc31bf26c52fcaed3917b813fe34b91f4137a308')
prepare() {
cd "${srcdir}/ringojs"
patch -i "${srcdir}/patch.diff" -p0 -s
}
build() {
cd "${srcdir}/ringojs"
ant update
ant jar
}
package() {
mkdir -p "${pkgdir}/usr/lib/${pkgname}"
for name in bin lib modules tools run.jar; do
cp -r "${srcdir}/ringojs/${name}" "${pkgdir}/usr/lib/${pkgname}/${name}"
done
mkdir -p "${pkgdir}/usr/bin"
for name in ringo ringo-admin ringo-web; do
ln -s "../lib/ringo/bin/${name}" "${pkgdir}/usr/bin/${name}"
done
}
|