blob: cd1c047c45e5da7e3c8b59f1211907fcc9f9ccf1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: twa022 <twa022 at gmail dot com>
_pkgname=RmlUi
pkgname=rmlui
pkgver=6.0
pkgrel=1
pkgdesc="The HTML/CSS User Interface library evolved"
arch=('i686' 'x86_64' 'aarch64' 'armv7h')
url="https://mikke89.github.io/RmlUiDoc/"
license=('MIT')
depends=('boost-libs' 'freetype2' 'libgl' 'glu')
makedepends=('cmake' 'mesa' 'boost' 'luajit')
optdepends=('luajit: Lua bindings')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/mikke89/RmlUi/archive/${pkgver}.tar.gz")
sha256sums=('aba3d4b8691076750eee6bf52d722db7880dfe74c18aebd8c6d676e43175fb78')
prepare() {
cd "${_pkgname}-${pkgver}"
[ -d build ] && rm -fr build
mkdir build
}
build() {
cd "${_pkgname}-${pkgver}"/build
cmake \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_INSTALL_LIBDIR=/usr/lib \
-DRMLUI_SAMPLES=OFF \
-DRMLUI_LUA_BINDINGS=ON \
-DRMLUI_LUA_BINDINGS_LIBRARY=luajit \
..
make
}
package() {
cd "${_pkgname}-${pkgver}"
make -C build install DESTDIR="${pkgdir}"
# license
install -Dm644 LICENSE.txt "${pkgdir}"/usr/share/licenses/"${pkgname}"/LICENSE
}
|