PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer: Angelo Elias Dal Zotto <angelodalzotto97@gmail.com>

_pkgroot=navigation2
_pkgname=nav2_smac_planner
pkgname=ros2-humble-nav2-smac-planner
pkgver=1.1.7
pkgrel=2
pkgdesc="Smac global planning plugin: A*, Hybrid-A*, State Lattice"
url="https://index.ros.org/p/nav2_smac_planner/"
arch=('any')
depends=(
    'ros2-humble' 
    'ros2-humble-nav2-util'
    'ros2-humble-nav2-msgs'
    'ros2-humble-nav2-common'
    'ros2-humble-nav2-costmap-2d'
    'ros2-humble-nav2-core'
    'ompl'
    'ode'
    'nlohmann-json'
    'ros2-humble-angles'
    'eigen'
)
makedepends=('cmake')
source=("https://github.com/ros-planning/navigation2/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('1d89dc1ad7c75d4d1645c882a5aee037ca965908344a158bb9669ad80a85196b')


build() {
    source /opt/ros/humble/setup.bash

    cmake -B build -S "$_pkgroot-$pkgver/$_pkgname" \
        -DCMAKE_BUILD_TYPE='None' \
        -DCMAKE_INSTALL_PREFIX='/opt/ros/humble' \
        -Wno-dev
    
    cmake --build build
}

package() {
    DESTDIR="$pkgdir" cmake --install build
}