blob: f6ab5da14c58cbba7af6d55bcbab54526897efcb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Mario Finelli <mario at finel dot li>
# Contributor: Andrew Rabert <draje@nullsum.net>
_gemname=exifr
pkgname=ruby-${_gemname}
pkgver=1.4.0
pkgrel=1
pkgdesc="Module to read EXIF from JPEG and TIFF images"
arch=(any)
url=https://github.com/remvee/exifr
license=(MIT)
options=(!emptydirs)
depends=(ruby)
checkdepends=(ruby-rake ruby-test-unit)
makedepends=(rubygems ruby-rdoc)
source=(${url}/archive/release-$pkgver/$_gemname-$pkgver.tar.gz)
sha256sums=('eb0bdd795476adff27bf3b9fbb2c98b58e00b310973a2956e8b5c622967f9f15')
build() {
cd $_gemname-release-$pkgver
local _gemdir="$(gem env gemdir)"
gem build "${_gemname}.gemspec"
gem install \
--local \
--verbose \
--ignore-dependencies \
--no-user-install \
--install-dir "tmp_install/${_gemdir}" \
--bindir "tmp_install/usr/bin" \
"${_gemname}-${pkgver}.gem"
# remove unrepreducible files
rm --force --recursive --verbose \
"tmp_install/${_gemdir}/cache/" \
"tmp_install/${_gemdir}/gems/${_gemname}-${pkgver}/vendor/" \
"tmp_install/${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"
find "tmp_install/${_gemdir}/gems/" \
-type f \
\( \
-iname "*.o" -o \
-iname "*.c" -o \
-iname "*.so" -o \
-iname "*.time" -o \
-iname "gem.build_complete" -o \
-iname "Makefile" \
\) \
-delete
find "tmp_install/${_gemdir}/extensions/" \
-type f \
\( \
-iname "mkmf.log" -o \
-iname "gem_make.out" \
\) \
-delete
}
check() {
cd $_gemname-release-$pkgver
local _gemdir="$(gem env gemdir)"
GEM_HOME="tmp_install/${_gemdir}" rake
}
package() {
cd $_gemname-release-$pkgver
cp --archive --verbose tmp_install/* "${pkgdir}"
install -v -Dm0644 MIT-LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -v -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
install -v -Dm0644 CHANGELOG "$pkgdir/usr/share/doc/$pkgname/CHANGELOG"
}
# vim: set ts=2 sw=2 et:
|