PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106

# Maintainer: Claudia Pellegrino <aur ät cpellegrino.de>

pkgname=ruby-jekyll-include-cache
_name=jekyll-include-cache
pkgver=0.2.1
pkgrel=1
pkgdesc='Jekyll plugin to cache the rendering of Liquid includes'
arch=('any')
url='https://github.com/benbalter/jekyll-include-cache'
license=('MIT')
depends=(
  'jekyll'
  'ruby'
)
makedepends=(
  'ruby-rake'
  'rubygems'
)
checkdepends=(
  'ruby-rspec'
)

source=(
  "${pkgname}-${pkgver}.tar.gz::https://github.com/benbalter/jekyll-include-cache/archive/v${pkgver}.tar.gz"
)

sha512sums=(
  '5e10d533fd7daeb76bda45d203575c4bf1c363be0fe996f62dc149169e7632286a5f60e5f2a734b2d173b4eca10b166f5dafc799d0adcdf14051bc68b58f0eae'
)

prepare() {
  cd "${_name}-${pkgver}"

  # update gemspec/Gemfile to allow newer version of the dependencies
  sed --in-place --regexp-extended 's|~>|>=|g' \
    "${_name}.gemspec"

  # we don't build from a git checkout
  sed --in-place --regexp-extended 's|git ls-files app lib|find lib -type f|' \
    "${_name}.gemspec"
}

build() {
  cd "${_name}-${pkgver}"

  local _gemdir
  _gemdir="$(gem env gemdir)"

  gem build "${_name}.gemspec"

  gem install \
    --local \
    --verbose \
    --ignore-dependencies \
    --build-root "tmp_install" \
    "${_name}-${pkgver}.gem"

  # remove unrepreducible files
  rm --force --recursive --verbose \
    "tmp_install/${_gemdir}/cache/" \
    "tmp_install/${_gemdir}/gems/${_name}-${pkgver}/vendor/" \
    "tmp_install/${_gemdir}/doc/${_name}-${pkgver}/ri/ext/"

  find "tmp_install/${_gemdir}/gems/" \
    -type f \
    \( \
      -iname "*.o" -o \
      -iname "*.c" -o \
      -iname "*.so" -o \
      -iname "*.time" -o \
      -iname "gem.build_complete" -o \
      -iname "Makefile" \
    \) \
    -delete

  find "tmp_install/${_gemdir}/extensions/" \
    -type f \
    \( \
      -iname "mkmf.log" -o \
      -iname "gem_make.out" \
    \) \
    -delete

  rmdir \
    "tmp_install/${_gemdir}/build_info/" \
    "tmp_install/${_gemdir}/extensions/" \
    "tmp_install/${_gemdir}/plugins/"
}

check() {
  cd "${_name}-${pkgver}"

  local _gemdir
  gemdir="$(gem env gemdir)"

  GEM_HOME="tmp_install/${_gemdir}" rspec
}

package() {
  cd "${_name}-${pkgver}"

  cp --archive --verbose tmp_install/* "${pkgdir}"

  install --verbose -D --mode=0644 LICENSE.md --target-directory "${pkgdir}/usr/share/licenses/${pkgname}"
  install --verbose -D --mode=0644 README.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
}