blob: 24d07e383d31d84649271d7dc917548445d2bf38 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Maintainer: Mario Finelli <mario at finel dot li>
_gemname=process_executer
pkgname=ruby-$_gemname
pkgver=1.1.0
pkgrel=1
pkgdesc="An API for executing commands in a subprocess"
arch=(any)
url=https://github.com/main-branch/process_executer
license=(MIT)
depends=(ruby)
checkdepends=(ruby-rake ruby-rspec ruby-simplecov)
makedepends=(rubygems ruby-rdoc)
options=(!emptydirs)
source=(${_gemname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz
disable-simplecov-lcov.patch)
sha256sums=('f0708822cd2b680b988b485203eaff644db165d2bb509026956549341747d04f'
'15aff615d2f63dbda8239b61ac9b03b6fb474d188f098b9b0de52af56fecc44c')
prepare() {
cd "${_gemname}-${pkgver}"
sed -i 's|~>|>=|g' ${_gemname}.gemspec
sed -i 's|git ls-files -z|find -print0|' ${_gemname}.gemspec
patch -p1 -N -i "$srcdir/disable-simplecov-lcov.patch"
}
build() {
cd "${_gemname}-${pkgver}"
local _gemdir="$(gem env gemdir)"
gem build "${_gemname}.gemspec"
gem install \
--local \
--verbose \
--ignore-dependencies \
--no-user-install \
--install-dir "tmp_install/${_gemdir}" \
--bindir "tmp_install/usr/bin" \
"${_gemname}-${pkgver}.gem"
# remove unrepreducible files
rm --force --recursive --verbose \
"tmp_install/${_gemdir}/cache/" \
"tmp_install/${_gemdir}/gems/${_gemname}-${pkgver}/vendor/" \
"tmp_install/${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"
find "tmp_install/${_gemdir}/gems/" \
-type f \
\( \
-iname "*.o" -o \
-iname "*.c" -o \
-iname "*.so" -o \
-iname "*.time" -o \
-iname "gem.build_complete" -o \
-iname "Makefile" \
\) \
-delete
find "tmp_install/${_gemdir}/extensions/" \
-type f \
\( \
-iname "mkmf.log" -o \
-iname "gem_make.out" \
\) \
-delete
}
check() {
cd $_gemname-$pkgver
local _gemdir="$(gem env gemdir)"
GEM_HOME="tmp_install/${_gemdir}" rspec
}
package() {
cd "${_gemname}-${pkgver}"
cp --archive --verbose tmp_install/* "${pkgdir}"
install -Dm0644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
# vim: set ts=2 sw=2 et:
|