blob: 2f70fcc96167289685eabf7a68ae6326c0a68aec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
# Maintainer: Morten Linderud <foxboron@archlinux.org>
# Contributor: Sébastien Luttringer
# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor: Christer Edwards <christer.edwards@gmail.com>
# Contributor: zer0def <zer0def@github>
pkgname=salt
pkgver=3007.1
pkgrel=1
pkgdesc='Central system and configuration manager'
arch=('any')
url='http://saltstack.org/'
license=('Apache')
replaces=('salt-zmq' 'salt-raet')
conflicts=('salt-zmq' 'salt-raet')
depends=('python-jinja'
'python-jmespath'
'python-msgpack'
'python-yaml'
'python-markupsafe'
'python-requests'
'python-distro'
'python-psutil'
'python-packaging'
'python-looseversion'
'python-pyzmq'
'python-m2crypto'
'python-systemd'
'python-importlib-metadata'
'python-pycryptodomex')
makedepends=('python-setuptools')
optdepends=('dmidecode: decode SMBIOS/DMI tables'
'python-pygit2: gitfs support')
#checkdepends=('python-pytest' 'python-psutil')
backup=('etc/logrotate.d/salt'
'etc/salt/master'
'etc/salt/minion')
install=salt.install
source=("https://pypi.io/packages/source/s/salt/salt-$pkgver.tar.gz"
salt.logrotate)
sha256sums=('b933ac4cb3e4b1118b46dada55c9cc6bdc6f0f94b4c92877aec44b25c6a28c9a'
'abecc3c1be124c4afffaaeb3ba32b60dfee8ba6dc32189edfa2ad154ecb7a215')
prepare() {
cd salt-$pkgver
sed -i '/^contextvars/d' requirements/base.txt
# remove version requirements for pyzmq, there's no point in it
# we only have one version and the "python_version <=> *" checks are discarded
# so pyzmq<=20.0.0 ends up in the final requirements.txt
echo -e '-r crypto.txt\n\npyzmq' > requirements/zeromq.txt
}
build() {
cd salt-$pkgver
python setup.py build
}
# TODO: Missing salt-factories, pytest-tempdir
# check() {
# local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
# cd salt-$pkgver
# python setup.py install --root="$PWD/tmp_install" --optimize=1
# PYTHONPATH="$PWD/tmp_install/$site_packages:$PYTHONPATH" py.test
# }
package() {
install -Dm644 salt.logrotate "$pkgdir"/etc/logrotate.d/salt
cd salt-$pkgver
python setup.py --salt-pidfile-dir="/run/salt" install --root="$pkgdir" --optimize=1 --skip-build
# default config
install -v -Dm644 conf/master "$pkgdir/etc/salt/master"
install -v -Dm644 conf/minion "$pkgdir/etc/salt/minion"
# systemd services
for _svc in salt-master.service salt-syndic.service salt-minion.service salt-api.service; do
install -v -Dm644 pkg/common/$_svc "$pkgdir/usr/lib/systemd/system/$_svc"
done
install -v -Dm644 pkg/common/salt.bash "$pkgdir/usr/share/bash-completion/completions/salt"
install -v -Dm644 pkg/common/salt.zsh "$pkgdir/usr/share/zsh/site-functions/_salt"
install -v -Dm644 -t "$pkgdir/usr/share/fish/vendor_completions.d" pkg/common/fish-completions/*
}
# vim:set ts=2 sw=2 et:
|