blob: d6ffd6a24b1e920a42f156d9739c89cf1a77edea (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Mike Yuan <me@yhndnzj.com>
pkgname=sbupdate-mkinitcpio
_srcname=sbupdate
pkgver=1.6
pkgrel=1
pkgdesc="Generate signed Unified Kernel Images"
arch=('any')
url="https://github.com/YHNdnzj/sbupdate"
license=('GPL3')
provides=('sbupdate')
conflicts=('sbupdate' 'sbupdate-git')
backup=("etc/sbupdate.conf")
install=sbupdate.install
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
b2sums=('a996b176f463efae04c8a0b92f4554deb011d95744c2ca9229a859d18466d9ea626ce3b3625b7870799684187c9533ce3d7253329f44065550475ce15167c498')
package() {
depends=('bash' 'systemd' 'systemd-ukify>=254rc1' 'mkinitcpio' 'sbsigntools')
cd "$_srcname-$pkgver"
sed -e 's|\(_f_config\)=.*|\1=/etc/sbupdate.conf|' \
-e 's|\(_f_functions\)=.*|\1=/usr/lib/initcpio/functions|' \
-i sbupdate
install -Dm755 sbupdate "$pkgdir/usr/bin/sbupdate"
install -Dm644 sbupdate.conf "$pkgdir/etc/sbupdate.conf"
install -dm755 "$pkgdir/usr/lib/initcpio/post"
ln -s /usr/bin/sbupdate "$pkgdir/usr/lib/initcpio/post/sbupdate"
install -Dt "$pkgdir/usr/lib/systemd/system" -m644 units/*
install -Dm644 README.md "$pkgdir/usr/share/doc/$_srcname/README.md"
}
# vim: set ts=4 sw=4 et:
|