PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: amateurece <ethan.twardy at gmail dot com>

pkgname=sdbusplus-git
pkgver=r598.a8a092c0
pkgrel=3
pkgdesc="C++ bindings for systemd dbus APIs"
url="https://github.com/openbmc/sdbusplus"
arch=('i686' 'x86_64' 'aarch64')
license=('Apache')
depends=('systemd-libs' 'python-mako' 'python-inflection' 'python-yaml')
makedepends=('git' 'meson' 'python-setuptools')
source=("${pkgname}::git+https://github.com/openbmc/sdbusplus.git")
sha256sums=('SKIP')

_meson_setup() {
    arch-meson -Dtests=disabled -Dexamples=disabled "${pkgname}" build
}

prepare() {
    _meson_setup
}

pkgver() {
    cd "${pkgname}"
    echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

build() {
    _meson_setup
    meson compile -C build

    # Python tools
    cd "${pkgname}/tools"
    python setup.py build
}

package() {
    meson install -C build --destdir "$pkgdir"
    cd "${pkgname}/tools"
    python setup.py install --root="$pkgdir" --optimize=1
}