PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: Sainnhe Park <sainnhe@gmail.com>
pkgname=sddm-sugar-candy-git
pkgver=r53.2b72ef6
pkgrel=1
pkgdesc="Sugar Candy is the sweetest login theme available for the SDDM display manager."
arch=('any')
url='https://store.kde.org/p/1312658/'
license=('GPL3')
depends=('sddm' 'qt5-graphicaleffects' 'qt5-quickcontrols2' 'qt5-svg')
makedepends=('git')
provides=("sddm-sugar-candy")
conflicts=("sddm-sugar-candy")
backup=('usr/share/sddm/themes/sugar-candy/theme.conf')
source=('sugar-candy::git+https://framagit.org/MarianArlt/sddm-sugar-candy.git')
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/sugar-candy"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
  cd "$srcdir/sugar-candy"
  install -Dm644 "Main.qml" "$pkgdir/usr/share/sddm/themes/sugar-candy/Main.qml"
  install -Dm644 "theme.conf" "$pkgdir/usr/share/sddm/themes/sugar-candy/theme.conf"
  install -Dm644 "metadata.desktop" "$pkgdir/usr/share/sddm/themes/sugar-candy/metadata.desktop"
  find ./Assets -type f -exec install -Dm644 {} "$pkgdir/usr/share/sddm/themes/sugar-candy/{}" \;
  find ./Backgrounds -type f -exec install -Dm644 {} "$pkgdir/usr/share/sddm/themes/sugar-candy/{}" \;
  find ./Components -type f -exec install -Dm644 {} "$pkgdir/usr/share/sddm/themes/sugar-candy/{}" \;
  install -Dm 644 "COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}

# vim:set ts=2 sw=2 et: