blob: c0a17143b40c1789c56aa8f128a524d3b3e895e8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: orhun <orhunparmaksiz@gmail.com>
# https://github.com/orhun/pkgbuilds
pkgname=sic-image-cli
_pkgname=sic
pkgver=0.22.4
pkgrel=1
pkgdesc="Accessible image processing and conversion from the terminal"
arch=('x86_64')
url="https://github.com/foresterre/sic"
license=('MIT')
conflicts=("$_pkgname")
depends=('gcc-libs')
makedepends=('cargo' 'nasm')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('bf3d324c41b3026e3ce15b4c2c0630a1c0165d9b04599a7f23604ec5c7c41098a368d9f7c127e176a2dcb98b4186dcbf6a25ab3d8e7fe1fc5b3578897e6781a7')
options=('!lto')
prepare() {
cd "$_pkgname-$pkgver"
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "$_pkgname-$pkgver"
cargo build --release --frozen --all-features
cargo run --example gen_completions
}
check() {
cd "$_pkgname-$pkgver"
cargo test --frozen
}
package() {
cd "$_pkgname-$pkgver"
install -Dm 755 "target/release/$_pkgname" -t "$pkgdir/usr/bin"
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm 644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm 644 "$_pkgname.bash" "${pkgdir}/usr/share/bash-completion/completions/$_pkgname"
install -Dm 644 "$_pkgname.fish" -t "${pkgdir}/usr/share/fish/completions"
install -Dm 644 "_$_pkgname" -t "${pkgdir}/usr/share/zsh/site-functions"
}
|