blob: a80c708592a8165d54801349f9c4f51bddd4b0ad (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
|
# Maintainer: orhun <orhunparmaksiz@gmail.com>
# https://github.com/orhun/pkgbuilds
pkgname=slicer
pkgdesc="A tool to automate the boring process of APK recon"
pkgver=1.5
pkgrel=1
arch=('x86_64')
url="https://github.com/mzfr/slicer"
license=('GPL3')
depends=('glibc')
makedepends=('go')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('6c49a0855f794e24da552de34f8f056fca853fb8932d99bffbfdb09fd776427f885095fdf65ecdde3624863cf9c38cc40c1ee139ebca5714a0feddc55f0ee24a')
build() {
cd "$pkgname-$pkgver"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o "$pkgname" .
}
package() {
cd "$pkgname-$pkgver"
install -Dm 755 "$pkgname" -t "$pkgdir/usr/bin"
install -Dm 644 readme.md -t "$pkgdir/usr/share/doc/$pkgname"
}
|