PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Phantasm <phantasm@centrum.cz>
# Based on the official Arch Linux PKGBUILD

pkgname=soundkonverter-dark-theme-git
pkgver=3.0.1.32.gdd52d33
pkgrel=1
pkgdesc="Front-end to various audio converters (Git - with custom colors for dark themes)"
arch=(x86_64)
url="https://store.kde.org/p/1126634"
license=(GPL)
depends=(hicolor-icon-theme cdparanoia kdelibs4support libkcddb5 kdbusaddons5 taglib phonon-qt5)
makedepends=(extra-cmake-modules kdesignerplugin kdoctools5 kinit git)
optdepends=('faac: faac backend'
            'faad2: faad backend'
            'ffmpeg: ffmpeg backend'
            'flac: flac backend'
            'fluidsynth: flouidsynth backend'
            'lame: lame backend'
            'mac: mac backend'
            'mplayer: mplayer backend'
            'opus-tools: opus backend'
            'speex: speexenc, speexdec backends'
            'timidity++: midi backend'
            'twolame: twolame backend'
            'vorbisgain: vorbisgain backend'
            'vorbis-tools: vorbis tools backend'
            'wavpack: wavpack backend'
            'sox: sox plugin (change sample rate, various effects)')
source=("git+https://github.com/nphantasm/soundkonverter.git")
provides=(soundkonverter)
conflicts=(soundkonverter)
sha256sums=('SKIP')

pkgver() {
	cd "$srcdir"/soundkonverter
	echo "$(git describe --long --tags | tr - . | tr -d v)"
}

build() {
	cmake -S soundkonverter/src -B build \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DLIB_INSTALL_DIR=lib \
		-DCMAKE_BUILD_TYPE=Release \
		-DKDE_INSTALL_USE_QT_SYS_PATHS=ON

	cmake --build build
}

package() {
	DESTDIR="$pkgdir" cmake --install build
}