blob: 27670fa14cfe258a8492da3e54ba6ed2612512d1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Contributor: Piotr Rogoza <piotr.r.public at gmail dot com>
# Contributor: Austin Keller <austin.keller@smartsheet.com>
# Maintainer: tee < teeaur at duck dot com >
pkgbase=sqlitestudio
pkgname=(
sqlitestudio
sqlitestudio-plugins
)
_pkgname=SQLiteStudio
pkgver=3.4.17
pkgrel=1
pkgdesc='Database manager for SQLite'
arch=(i686 x86_64)
url='https://sqlitestudio.pl'
_git='https://github.com/pawelsalawa/sqlitestudio'
license=('GPL3')
depends=(
qt5-script
qt5-declarative
)
makedepends=(
qt5-svg
qt5-tools
qt5-wayland
python
tcl
)
source=(
${_git}/archive/refs/tags/${pkgver}.tar.gz
${pkgbase}.desktop
)
noextract=(
${pkgver}.tar.gz
)
sha256sums=('17662e1aa9bc3e70639a51a34a12ba707e52a475d2742fa8ab9ecad621ff6caf'
'c5a26a9b9003b04274887a0e0febda13eea49bb46c618eaad0b5b5c88b1cc1d2')
prepare(){
cd "$srcdir"
tar -xf ${pkgver}.tar.gz --strip-components=1
}
build(){
cd "$srcdir"
install -dm755 "$srcdir"/output/build/Plugins
msg2 "Making sqlitestudio3-main"
cd "$srcdir"/output/build
qmake ../../SQLiteStudio3 \
"LIBS += -L$srcdir/SQLiteStudio3/coreSQLiteStudio/services/impl"
make -s
msg2 "Making sqlitestudio3-plugins"
cd "$srcdir"/output/build/Plugins
ver="$(python -c"import sys;print(sys.version_info.major,sys.version_info.minor,sep='.')")"
qmake ../../../Plugins \
"PYTHON_VERSION = $ver" \
"INCLUDEPATH += $srcdir/SQLiteStudio3/coreSQLiteStudio" \
"INCLUDEPATH += /usr/include/python$ver"
(
cd $srcdir/Plugins/DbSqliteCipher
ln -sf $srcdir/SQLiteStudio3/coreSQLiteStudio/plugins
ln -sf $srcdir/SQLiteStudio3/coreSQLiteStudio/db
)
make -s -j1
}
package_sqlitestudio(){
cd "$srcdir"/output/build
make INSTALL_ROOT="$pkgdir/usr" install
install -Dm644 $srcdir/sqlitestudio.desktop \
$pkgdir/usr/share/applications/sqlitestudio.desktop
install -Dm755 \
"$srcdir"/SQLiteStudio3/guiSQLiteStudio/img/sqlitestudio.svg \
"$pkgdir"/usr/share/pixmaps/sqlitestudio.svg
}
package_sqlitestudio-plugins(){
pkgdesc='Official plugins for sqlitestudio'
depends=(sqlitestudio tcl python)
cd $srcdir/output/build/Plugins
make INSTALL_ROOT="$pkgdir/usr" install
}
# vim:set noet sts=0 sw=4 ts=4 ft=PKGBUILD:
|