blob: 882a6d1b4239cf22d030429ef6bbc678f74ab6cd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: robertfoster
pkgname=stable-diffusion.cpp-hipblas-git
pkgver=r211.10c6501
pkgrel=1
pkgdesc="Stable Diffusion in pure C/C++ (with AMD ROCm optimizations)"
arch=('armv7h' 'aarch64' 'x86_64')
url="https://github.com/leejet/stable-diffusion.cpp"
license=("MIT")
depends=('hipblas')
makedepends=(
'cmake'
'git'
'rocm-hip-sdk'
)
conflicts=("${pkgname%%-git}" 'stable-diffusion.cpp')
conflicts=("${pkgname%%-git}" 'stable-diffusion.cpp')
source=("${pkgname%%-git}::git+${url}"
"git+https://github.com/ggerganov/ggml.git")
pkgver() {
cd "${srcdir}/${pkgname%%-git}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
prepare() {
cd "${srcdir}/${pkgname%%-git}"
git submodule init
git config submodule.ggml.url "${srcdir}/ggml"
git -c protocol.file.allow=always submodule update --remote
}
build() {
export CXXFLAGS+="$CXXFLAGS -fcf-protection=none"
CC=/opt/rocm/llvm/bin/clang CXX=/opt/rocm/llvm/bin/clang++ \
cmake \
-B "${srcdir}/build" \
-S "${srcdir}/${pkgname%%-git}" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DGGML_HIP=1
cmake --build build
}
package() {
DESTDIR="${pkgdir}" cmake --install "${srcdir}/build"
rm "${pkgdir}/usr/include/"ggml*
install -Dm644 "${srcdir}/${pkgname%%-git}/LICENSE" \
-t "${pkgdir}/usr/share/licenses/${pkgname}"
rm -rf "${pkgdir}/usr/include/gguf.h"
rm -rf "${pkgdir}/usr/lib/cmake/ggml/ggml-config.cmake"
rm -rf "${pkgdir}/usr/lib/cmake/ggml/ggml-version.cmake"
rm -rf "${pkgdir}"/usr/lib/*.a
}
sha256sums=('SKIP'
'SKIP')
|