blob: aaca1bac4049bce0a16a66b360b3e2cbf47bd08d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
pkgname=strawberry-lite-git
pkgver=1.2.7.r12.gd571bc330
pkgrel=2
pkgdesc="A music player aimed at audio enthusiasts and music collectors, fewer fautures, Gstreamer and alsa only"
arch=(x86_64 i686 armv7h aarch64)
url="https://www.strawberrymusicplayer.org/"
license=(GPL-3.0-or-later)
depends=(chromaprint gst-plugins-base gst-plugins-good qt6-base
sqlite udisks2 dbus alsa-lib libcdio fftw libebur128 kdsingleapplication
libicuuc.so libicui18n.so
# namcap implicit depends
glibc gcc-libs glib2 icu hicolor-icon-theme libx11 gstreamer
taglib gst-plugins-base-libs)
makedepends=(git cmake boost qt6-tools)
optdepends=('gst-libav: additional codecs'
'gst-plugins-bad: additional codecs'
'gst-plugins-ugly: additional codecs')
provides=(strawberry)
conflicts=(strawberry)
source=("git+https://github.com/jonaski/strawberry.git")
sha256sums=('SKIP')
pkgver() {
cd strawberry
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
local _flags=(
-DCMAKE_CXX_FLAGS="$CXXFLAGS -DQT_NO_DEBUG_OUTPUT"
-DENABLE_TIDAL=OFF
-DENABLE_QOBUZ=OFF
-DENABLE_SPOTIFY=OFF
-DENABLE_SUBSONIC=OFF
-DENABLE_GPOD=OFF
-DENABLE_MTP=OFF
-DENABLE_PULSE=OFF
-DENABLE_STREAMTAGREADER=OFF
)
cmake -B build -S "strawberry" -Wno-dev \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_INSTALL_PREFIX=/usr \
"${_flags[@]}"
cmake --build build
}
package() {
DESTDIR="${pkgdir}" cmake --install build
}
|