blob: 8e77f2ad456ac51aad676c0fea23256e128c0d80 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Eric Berquist <eric DOT berquist AT gmail DOT com>
# derived from community/tachyon
pkgname=tachyon-opengl
_pkgname=tachyon
pkgver=0.99b6
pkgrel=3
pkgdesc="Parallel ray tracer (used as part of Visual Molecular Dynamics), OpenGL-enabled"
arch=('i686' 'x86_64')
url="http://jedi.ks.uiuc.edu/~johns/raytracer/"
license=('custom')
depends=('libgl' 'libjpeg' 'libpng')
conflicts=('tachyon')
options=(staticlibs)
source=("http://jedi.ks.uiuc.edu/~johns/raytracer/files/${pkgver}/${_pkgname}-${pkgver}.tar.gz"
"make_arch.patch"
"make_config.patch"
"make_gl.patch")
sha256sums=('f4dcaf9c76a4f49310f56254390f9611c22e353947a1745a8c623e8bc8119b97'
'935553f4a0553505dc4db9c22635072d9cf238988e1dbeee2df52a01e0953a1a'
'c016bb5b0bc422c11bf53e93f7f9001fd742a53ab3d49affd1354bc3990391b3'
'0060bd52bad05e98a9709af4a84e758d17b376b4f7ab71e627f0aeeaf9e5f0e0')
case "$CARCH" in
"i686") _buildtype=linux-thr-ogl ;;
"x86_64") _buildtype=linux-64-thr-ogl ;;
esac
prepare() {
cd "${srcdir}/${_pkgname}/unix"
# generate position-independent code
patch -i "${srcdir}/make_arch.patch"
# enable JPEG and PNG support, plus GCC atomics
patch -i "${srcdir}/make_config.patch"
# fix location of OpenGL and X11 headers/libraries
patch -i "${srcdir}/make_gl.patch"
}
build() {
cd "${srcdir}/${_pkgname}/unix"
make ${_buildtype}
}
package() {
# binary and library
cd "${srcdir}/${_pkgname}/compile/${_buildtype}"
install -D -m 755 tachyon "${pkgdir}/usr/bin/tachyon"
install -D -m 644 libtachyon.a "${pkgdir}/usr/lib/libtachyon.a"
# headers
cd "${srcdir}/${_pkgname}/src"
install -d "${pkgdir}/usr/include/tachyon"
install -m 644 *.h "${pkgdir}/usr/include/tachyon"
# scenes
cd "${srcdir}/${_pkgname}/scenes"
install -d "${pkgdir}/usr/share/tachyon/scenes/imaps"
install -m 644 README *.dat *.cam *.ac "${pkgdir}/usr/share/tachyon/scenes"
install -m 644 imaps/* "${pkgdir}/usr/share/tachyon/scenes/imaps"
# license
cd "${srcdir}/${_pkgname}"
install -D -m 644 Copyright "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|