PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Yauhen Kirylau <actionless DOT loveless PLUS aur AT gmail MF com>
# Upstream URL: https://github.com/themix-project/themix-plugin-base16

_pkgname=themix-plugin-base16
_reponame=$_pkgname
pkgname="${_pkgname}-git"
pkgver=1.6.1
pkgrel=1
pkgdesc="Import and export plugin for Themix GUI designer to use color palettes from Base16 project (Alacritty, Emacs, GTK4, KDE, Qt5ct, Qt6ct, VIM and many more.)"
arch=('x86_64' 'i686')
url="https://github.com/themix-project/${_reponame}"
license=('GPL3')
source=(
	"${_reponame}::git+https://github.com/themix-project/${_reponame}.git#branch=master"
)
md5sums=('SKIP')
depends=(
	'themix-gui'
	'python-pystache'
	'python-yaml'
)
makedepends=(
	'git'
)
optdepends=(
)
options=(
	'!strip'
)
provides=($_pkgname)
conflicts=(
    $_pkgname
    'oomox'
    'oomox-git'
)

pkgver() {
	cd "${srcdir}/${_reponame}"
	git describe --always --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

package() {
	_oomox_dir=/opt/oomox
	_plugin_name=base16

	cd "${srcdir}/${_reponame}"
	make -f Makefile_oomox_plugin DESTDIR="${pkgdir}" APPDIR="${_oomox_dir}" PREFIX="/usr" install
	python -O -m compileall "${pkgdir}${_oomox_dir}/plugins/${_plugin_name}" -d "${_oomox_dir}/plugins/${_plugin_name}"
}

# vim: ft=PKGBUILD