PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

# Maintainer: Michał Wojdyła < micwoj9292 at gmail dot com >
# Contributor: Hugo Parente Lima <hugo.pl@gmail.com>

pkgname=tijolo-git
pkgver=0.8.1+13+g8b14d81
pkgrel=1
pkgdesc="Simple and fast keyboard focused IDE written in Crystal and GTK."
arch=("x86_64")
conflicts=("tijolo")
provides=("tijolo")
url="https://github.com/hugopl/tijolo"
license=("MIT")
depends=("graphene" "vulkan-icd-loader" "hicolor-icon-theme" "libadwaita" "libevent" "pcre2" "gc" "vte4" "gtksourceview5" "gdk-pixbuf2" "gcc-libs" "glibc" "glib2" "pango" "dconf" "gtk4" "harfbuzz" "cairo")
makedepends=("git" "shards" "crystal" "gobject-introspection-runtime")
source=("tijolo-git::git+https://github.com/hugopl/tijolo.git")
sha256sums=('SKIP')

pkgver() {
  cd "$pkgname"
  git describe --tags | sed s/-/+/g | sed s/v//
}

build() {
  cd "$srcdir/tijolo-git"
  make
}

package() {
  cd "$srcdir/tijolo-git"
  make install DESTDIR="${pkgdir}"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}