PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=tree-sitter-agda-git
pkgver=1.3.3.r1.gb9b32fa
pkgrel=3
pkgdesc="Agda grammar for tree-sitter"
arch=('i686' 'x86_64')
url="https://github.com/tree-sitter/tree-sitter-agda"
license=('MIT')
groups=('tree-sitter-grammars')
depends=('glibc')
makedepends=('git' 'nodejs' 'tree-sitter-cli')
provides=("tree-sitter-agda=$pkgver" 'libtree-sitter-agda.so')
conflicts=('tree-sitter-agda')
options=('staticlibs')
source=("git+https://github.com/tree-sitter/tree-sitter-agda.git")
sha256sums=('SKIP')


pkgver() {
  cd "tree-sitter-agda"

  _tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "tree-sitter-agda"

  tree-sitter generate
  CFLAGS="$CFLAGS -ffat-lto-objects" \
  make
}

check() {
  cd "tree-sitter-agda"

  #tree-sitter test
}

package() {
  cd "tree-sitter-agda"

  make DESTDIR="$pkgdir" PREFIX="/usr" install
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/tree-sitter-agda"
  install -Dm644 "README.md" -t "$pkgdir/usr/share/doc/tree-sitter-agda"
}