PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

# Maintainer:  Jonathon Fernyhough <jonathon at+m2x dev>
# Contributor: Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: Romain Bouchaud-Leduc <r0m1.bl@camaris.org>

pkgname=trickle-git
pkgver=r23.09a1d95
pkgrel=3
pkgdesc="Lightweight userspace bandwidth shaper"
arch=('i686' 'x86_64' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/mariusae/trickle"
license=('BSD')
depends=('libevent' 'libtirpc')
makedepends=('git')
provides=("${pkgname/-git/}")
conflicts=("${pkgname/-git/}")
source=("git+$url.git"
        "remove-libtrickle.patch"
        "fix-trickle-overload.patch"
        "$url/pull/28/commits/4171f1716eb2e37d36fb9189800c53b83723569d.patch"
        "$url/pull/29/commits/29de2a4704d9843d3c6cba1d4a4ac177f2d6e568.patch")
sha256sums=('SKIP'
            '7e148c9526dbd6667c94ce3ee4f1a1fd550e61ab185735939c4d5312cf13b7a1'
            'd3f91fa4b05777c936cb95fbfee04b5955e366755e682368e626d004f07d9c75'
            'dfffeb04a403e7eeb67e0fd5e611f2e428569b68139324fe7af8dee7e7b7cacb'
            '0b5ae4357c8b383b30235172a10b673eb2bfa5d640cfe86dd0b890d0d8c3dcc0')

pkgver() {
	cd ${pkgname/-git/}
	# https://wiki.archlinux.org/index.php/VCS_package_guidelines#The_pkgver.28.29_function
	( set -o pipefail
	git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	)
}

prepare() {
	cd ${pkgname/-git/}

	# https://github.com/mariusae/trickle/issues/16
	patch -Np1 -i ../remove-libtrickle.patch

	# https://aur.archlinux.org/packages/trickle-git#comment-885736
	# https://github.com/mariusae/trickle/pull/29
	patch -Np1 -i ../fix-trickle-overload.patch

	# Fix rpc support, https://github.com/mariusae/trickle/pull/28
	patch -Np1 -i ../4171f1716eb2e37d36fb9189800c53b83723569d.patch

	# Use $libdir for preload object lookup, https://github.com/mariusae/trickle/pull/29
	patch -Np1 -i ../29de2a4704d9843d3c6cba1d4a4ac177f2d6e568.patch
}

build() {
	cd ${pkgname/-git/}

	autoreconf -if
	./configure --prefix=/usr \
		--mandir=/usr/share/man
	make -j1
}

package() {
	cd ${pkgname/-git/}

	make DESTDIR="${pkgdir}" install
	install -Dm644 -t "${pkgdir}"/usr/share/licenses/${pkgname}/ LICENSE
}