PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>

pkgname=trojita-git
pkgver=0.7.r723.g5338fea9
pkgrel=2
pkgdesc="A fast QT IMAP e-mail client"
arch=(i686 x86_64)
url="http://trojita.flaska.net"
license=('GPL')
depends=('qt5-webkit' 'qtkeychain' 'qt5-tools' 'qt5-svg' 'mimetic'
         'qgpgme-qt5' 'desktop-file-utils' 'sonnet5' 'ragel')
conflicts=('trojita')
provides=('trojita')
makedepends=('git' 'cmake' 'boost')

source=('git+https://invent.kde.org/pim/trojita.git'
        'trojita-qgpgme5.patch')
md5sums=('SKIP'
         '8439d6c1546e5a3a624f023cc1a473e3')

pkgver() {
  cd "$srcdir/trojita"
  git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$srcdir/trojita"
  patch -Np1 < "${srcdir}"/trojita-qgpgme5.patch
}

build() {
  cd "$srcdir/trojita"
  cmake -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DWITH_TESTS=OFF \
        -DWITH_QT5=ON \
        -DWITH_QTKEYCHAIN_PLUGIN=ON \
        -DWITH_GPGMEPP=ON \
        -DWITH_CRYPTO_MESSAGES=ON \
        -DCMAKE_PREFIX_PATH=/usr/lib/cmake/QGpgmeQt5 \
        .
  make
}

package() {
  cd "$srcdir/trojita"
  make install DESTDIR="$pkgdir"
}