PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25

# Maintainer: Daniel Peukert <daniel@peukert.cc>
# Contributor: Brian Weasner <weasnerb at gmail dot com>
_projectname='MaterialDesign-Webfont'
pkgname='ttf-material-design-icons-webfont'
pkgver='7.4.47'
pkgrel='1'
pkgdesc='Material Design webfont icons from materialdesignicons.com'
arch=('any')
url='https://materialdesignicons.com'
license=('Apache-2.0')
checkdepends=('fontconfig')
source=("$pkgname-$pkgver.tar.gz::https://github.com/Templarian/$_projectname/archive/v$pkgver.tar.gz")
sha512sums=('31f3494be5fcde45a3a0138948b1ec0a73b56f8a999449cfd96c7eacd8d1dbae0fdc7e76f7da4b61b1e53e3b28fd21a9369ab190317067f62c1e643b908eec61')

_sourcedirectory="$_projectname-$pkgver"

check() {
	_checkoutput="$(fc-scan "$srcdir/$_sourcedirectory/fonts/materialdesignicons-webfont.ttf")"
	printf '%s\n' "$_checkoutput"
	printf '%s\n' "$_checkoutput" | grep -q 'family: "Material Design Icons"'
}

package() {
	install -Dm644 "$srcdir/$_sourcedirectory/fonts/materialdesignicons-webfont.ttf" "$pkgdir/usr/share/fonts/TTF/materialdesignicons-webfont.ttf"
}