PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75

# Maintainer: Manuel Hüsers <aur@huesers.de>
# Contributor: Wes Jackson <icebal dot 7 at gmail dot com>
# Contributor: Iwan Timmer <irtimmer@gmail.com>
# Contributor: Timothée Ravier <tim at siosm dot fr>
# Contributor: Tom <reztho at archlinux dot org>

_pkgbase=tuned
pkgbase="${_pkgbase}-git"
pkgname=("${_pkgbase}-git" "${_pkgbase}-ppd-git")
pkgver=2.24.0.r6.g35eed3c
pkgrel=2
pkgdesc='Daemon that performs monitoring and adaptive configuration of devices in the system'
arch=('any')
url="https://github.com/redhat-performance/${_pkgbase}"
license=('GPL-2.0-or-later')
depends=('ethtool' 'gawk' 'hdparm' 'polkit' 'perf' 'python-configobj'
	'python-dbus' 'python-gobject' 'python-linux-procfs' 'python-pyudev')
makedepends=('desktop-file-utils' 'git')
source=("git+${url}.git")
sha512sums=('SKIP')

pkgver() {
	cd "${_pkgbase}"
	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/^v//g;s/-/./g'
}

prepare() {
	cd "${_pkgbase}"
	mv libexec lib

	sed -i 's|/libexec/|/lib/|g' Makefile
	sed -i 's|/sbin/|/bin/|g' Makefile tuned.service tuned-gui.py tuned-gui.desktop tuned/ppd/tuned-ppd.service
	sed -i 's|install-ppd: install$|install-ppd: install-dirs|' Makefile
}

package_tuned-git() {
	optdepends=('virt-what: Virtual machine detection'
		'systemtap: Detailed system monitoring'
		'tuned-ppd: power-profiles-daemon api translation'
		'wireless_tools: Wireless device power management'
		'x86_energy_perf_policy: Energy Performance Bias (EPB) support')
	provides=("${_pkgbase}")
	conflicts=("${_pkgbase}")
	backup=('etc/tuned/active_profile'
		'etc/tuned/bootcmdline'
		'etc/tuned/cpu-partitioning-powersave-variables.conf'
		'etc/tuned/cpu-partitioning-variables.conf'
		'etc/tuned/post_loaded_profile'
		'etc/tuned/profile_mode'
		'etc/tuned/realtime-variables.conf'
		'etc/tuned/realtime-virtual-guest-variables.conf'
		'etc/tuned/realtime-virtual-host-variables.conf'
		'etc/tuned/tuned-main.conf')

	cd "${_pkgbase}"

	make DESTDIR="${pkgdir}" install
	rm -rv "${pkgdir}"/{run,var}

	python -m compileall -d /usr/lib "${pkgdir}/usr/lib"
	python -O -m compileall -d /usr/lib "${pkgdir}/usr/lib"
}

package_tuned-ppd-git() {
	pkgdesc='Daemon that allows applications to easily transition to TuneD from power-profiles-daemon (PPD)'
	depends=("${_pkgbase}")
	provides=("${_pkgbase}-ppd" 'power-profiles-daemon')
	conflicts=("${_pkgbase}-ppd" 'power-profiles-daemon')
	backup=('etc/tuned/ppd.conf')
	options=('!emptydirs')

	cd "${_pkgbase}"

	make DESTDIR="${pkgdir}" install-ppd
}