PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Peter Mattern <pmattern at arcor dot de>
# Contributor: Helder Bertoldo <helder.bertoldo@gmail.com>

_pkgname=tuner
pkgname=$_pkgname-git
pkgver=1.5.1.r67.426d564
pkgrel=1
pkgdesc="GNU/Linux app to discover and play internet radio stations. Geared towards RadioBrowser"
arch=('i686' 'x86_64')
url="https://codeberg.org/$_pkgname/$_pkgname"
license=('GPL-3.0-only')
depends=('granite' 'gst-plugins-bad-libs' 'gst-plugins-good')
optdepends=('gst-libav: play AAC[+] streams')
makedepends=('git' 'meson' 'vala')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("git+${url}.git")
sha256sums=('SKIP')

pkgver() {
    cd "${_pkgname}"
    printf "%s" "$(git describe --long --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}

build() {
    cd "${_pkgname}/"
    meson . _build --prefix=/usr
    ninja -C _build
}

package() {
    cd "${_pkgname}/"
    DESTDIR="${pkgdir}" ninja -C _build install
    cd "${pkgdir}"/usr/bin/
    ln -s com.github.louis77.tuner tuner
}