blob: 73212a5eddf7f9944b1feaf1ebc10f23c85d3e95 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=turbobench-git
pkgver=2023.04.r16.g753b2ab
pkgrel=1
pkgdesc="Compressor benchmark program"
arch=('i686' 'x86_64')
url="https://github.com/powturbo/TurboBench"
license=('GPL2')
depends=('gcc-libs')
makedepends=('git')
provides=("turbobench=$pkgver")
conflicts=('turbobench')
source=("git+https://github.com/powturbo/TurboBench.git")
sha256sums=('SKIP')
prepare() {
cd "TurboBench"
git submodule update --init --recursive
}
pkgver() {
cd "TurboBench"
_tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9-]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//;s/-/./g'
}
build() {
cd "TurboBench"
make
}
package() {
cd "TurboBench"
install -Dm755 "turbobench" -t "$pkgdir/usr/bin"
install -Dm644 "README.md" -t "$pkgdir/usr/share/doc/turbobench"
}
|