PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: quietvoid <tcChlisop0@gmail.com>

_plug=awsmfunc
pkgname=vapoursynth-plugin-${_plug}-git
pkgver=1.3.4.r9.g0bdcb2d
pkgrel=1
pkgdesc='Plugin for VapourSynth: awsmfunc (GIT version)'
arch=('x86_64')
url='https://github.com/OpusGang/awsmfunc'
license=('MIT')
depends=('python-numpy'
         'vapoursynth-plugin-subtext'
         'vapoursynth-plugin-vsutil'
         'vapoursynth-plugin-rekt'
         'vapoursynth-plugin-remapframes'
         'vapoursynth-plugin-fillborders')
makedepends=('git'
             'python-build'
             'python-installer'
             'python-setuptools'
             'python-wheel')
optdepends=('vapoursynth-plugin-placebo: VapourSynth placebo plugin'
            'vapoursynth-plugin-descale: VapourSynth descale plugin'
            'vapoursynth-plugin-bilateral'
            'vapoursynth-plugin-fpng')
provides=("vapoursynth-plugin-${_plug}")
conflicts=("vapoursynth-plugin-${_plug}")
source=("${_plug}::git+https://github.com/OpusGang/awsmfunc.git")
sha256sums=('SKIP')

pkgver() {
    cd "${_plug}"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "${_plug}"
    python -m build --wheel --no-isolation
}

package() {
    cd "${_plug}"

    python -m installer --destdir="$pkgdir" dist/*.whl
    install -Dm644 README.md "${pkgdir}/usr/share/doc/vapoursynth/tools/${_plug}/README.md"
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}