blob: 831c43cd6bdf8362cb7136cb9945823d870b809d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: OSAMC <https://github.com/osam-cologne/archlinux-proaudio>
# Contributor: Florian Hülsmann <fh@cbix.de>
_slug=ChemicalElements
_name=chemical-elements
pkgname=vcvrack-chemical-elements
pkgver=2.0.0
pkgrel=2
pkgdesc='Chemical Elements VCV Rack modules'
arch=(aarch64 x86_64)
url='https://gitlab.com/pythongirl/chemical-elements'
license=(GPL-3.0-or-later)
groups=(pro-audio vcvrack-plugins)
depends=(gcc-libs vcvrack)
makedepends=(git jq simde zstd)
# get commit from https://github.com/VCVRack/library/tree/v2/repos
_commit=414e488e8db482e0d67a3294b2d8461ade36ac03
source=("git+https://gitlab.com/pythongirl/$_name#commit=$_commit")
sha256sums=('79b201abc903c5ff433626ebbcbee32370f6629270a621612cdb4961fa97dc1c')
prepare() {
cd $_name
if [ $(jq -r .version plugin.json) != $pkgver ]; then
echo "Make sure to update _commit"
false
fi
# common license
rm LICENSE
}
build() {
cd $_name
make SLUG=$_slug VERSION=$pkgver STRIP=: RACK_DIR=/usr/share/vcvrack dist
}
package() {
cd $_name
install -d "$pkgdir"/usr/lib/vcvrack/plugins
cp -va dist/$_slug -t "$pkgdir"/usr/lib/vcvrack/plugins
}
|