PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

# Maintainer: Daniele Fucini <dfucini [at] gmail [dot] com>
# Contributor: Luis Martinez <luis dot martinez at tuta dot io>
# Contributor: Rodrigo Gryzinski <rogryza@gmail.com>

pkgname=vim-dracula-git
_pkgname=vim-dracula
pkgver=2.0.0.r103.g65f4225
pkgrel=2
pkgdesc="A dark theme for Vim"
arch=('any')
url="https://draculatheme.com/vim"
license=('MIT')
groups=('vim-plugins')
depends=('vim-plugin-runtime')
makedepends=('git')
provides=('vim-dracula' 'vim-airline-dracula' 'vim-lightline-dracula')
conflicts=('vim-dracula' 'vim-airline-dracula' 'vim-lightline-dracula')
source=("${_pkgname}::git+https://github.com/dracula/vim")
sha512sums=('SKIP')

pkgver() {
	cd "${_pkgname}"
	git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
}

package() {
	cd "${_pkgname}"
	find autoload colors doc \
	  -type f -exec install -Dvm 644 '{}' "${pkgdir}/usr/share/vim/vimfiles/{}" \;
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}