blob: e5be539798fc866f45c966d14bf393fae999b178 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
|
# Maintainer: Luis Martinez <luis dot martinez at tuta dot io>
# Contributor: Aaron Griffin <aaron@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=vim-workspace-git
pkgver=1.8.3.r18.gfaa8354
pkgrel=2
pkgdesc="Vim workspace manager plugin for managing groups of files"
arch=('any')
url="https://github.com/thaerkh/vim-workspace"
license=('Apache')
groups=('vim-plugins')
depends=('vim-plugin-runtime')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("$pkgname::git+$url")
sha256sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --long --tags | sed 's/-/.r/;s/-/./'
}
package() {
cd "$pkgname"
find doc plugin \
-type f -exec install -Dvm 644 '{}' "$pkgdir/usr/share/vim/vimfiles/{}" \;
install -Dvm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
install -Dvm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
}
|