PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: Manuel Wiesinger <m {you know what belongs here} mmap {and here} at>
# Maintainer: Peter Jung <admin@ptr1337.dev>

_srcname=virtme-ng
pkgname=$_srcname-git
pkgver=1.31.r3.gcefbab5
pkgrel=1
pkgdesc="A tool that allows to easily and quickly recompile and test a Linux kernel, starting from the source code."
arch=('x86_64')
url="https://github.com/arighi/virtme-ng"
license=('GPL-2.0-only')
depends=(
  bash
  busybox
  coreutils
  gcc-libs
  glibc
  python
  python-argcomplete
  python-argparse-manpage
  python-requests
  python-setuptools
  qemu
  virtiofsd
)
makedepends=(
  cargo
  git
  python-build
  python-installer
  python-wheel
)
provides=('virtme=$pkgver')
conflicts=('virtme-ng')
source=("git+${url}.git"
        "git+https://github.com/arighi/virtme-ng-init.git")
b2sums=('SKIP'
        'SKIP')

pkgver() {
    cd "$srcdir/${_srcname}"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd "$srcdir/${_srcname}"
    git submodule update --init --filter=tree:0 --recursive
}

build() {
    cd "$srcdir/${_srcname}"
    export RUSTUP_TOOLCHAIN=stable
    BUILD_VIRTME_NG_INIT=1 python -m build --wheel --no-isolation
}

package() {
    cd "$srcdir/$_srcname"
    python -m installer --destdir="$pkgdir" dist/*.whl
}