1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
|
# Maintainer: loathingkernel <loathingkernel @at gmail .dot com>
pkgname=vkd3d-proton-mingw
pkgver=2.14.1
pkgrel=2
pkgdesc='Fork of VKD3D. Development branches for Protons Direct3D 12 implementation'
arch=('x86_64')
url="https://github.com/HansKristian-Work/vkd3d-proton"
license=('LGPL-2.1')
makedepends=('ninja' 'meson>=0.43' 'glslang' 'git' 'mingw-w64-gcc' 'mingw-w64-tools')
provides=('vkd3d-proton' 'd3d12.dll' "vkd3d-proton=$pkgver")
conflicts=('vkd3d-proton' 'd3d12.dll')
options=(!lto !staticlibs)
source=(
"git+https://github.com/HansKristian-Work/vkd3d-proton.git#tag=v$pkgver"
"vkd3d-proton-extraopts.patch"
"setup_vkd3d_proton.sh"
"setup_vkd3d_proton"
)
prepare() {
cd vkd3d-proton
# Explicitly set origin URL for submodules using relative paths
git remote set-url origin https://github.com/HansKristian-Work/vkd3d-proton.git
git submodule update --init --filter=tree:0 --recursive
# Uncomment to enable extra optimizations
# Patch crossfiles with extra optimizations from makepkg.conf
patch -p1 -i "$srcdir"/vkd3d-proton-extraopts.patch
# By default export FLAGS used by proton and ignore makepkg
# This overrides FLAGS from makepkg.conf, if you comment these you are on your own
local -a split=($CFLAGS)
local -A flags
for opt in "${split[@]}"; do flags["${opt%%=*}"]="${opt##*=}"; done
local march="${flags["-march"]:-nocona}"
local mtune="${flags["-mtune"]:-core-avx2}"
CFLAGS="-O3 -march=$march -mtune=$mtune -pipe"
CXXFLAGS="-O3 -march=$march -mtune=$mtune -pipe"
LDFLAGS="-Wl,-O1,--sort-common,--as-needed"
# These flags are taken from Proton
CFLAGS+=" -mfpmath=sse -fwrapv -fno-strict-aliasing"
CXXFLAGS+=" -mfpmath=sse -fwrapv -fno-strict-aliasing -std=c++17"
LDFLAGS+=" -Wl,--file-alignment,4096"
export CFLAGS CXXFLAGS LDFLAGS
local cross_ldflags="$LDFLAGS"
local cross_cflags="$CFLAGS -mcmodel=small"
local cross_cxxflags="$CXXFLAGS -mcmodel=small"
sed -i build-win64.txt \
-e "s|@CARGS@|\'${cross_cflags// /\',\'}\'|g" \
-e "s|@CXXARGS@|\'${cross_cxxflags// /\',\'}\'|g" \
-e "s|@LDARGS@|\'${cross_ldflags// /\',\'}\'|g"
local cross_cflags="$CFLAGS -mstackrealign -mpreferred-stack-boundary=2"
local cross_cxxflags="$CXXFLAGS -mstackrealign -mpreferred-stack-boundary=2"
sed -i build-win32.txt \
-e "s|@CARGS@|\'${cross_cflags// /\',\'}\'|g" \
-e "s|@CXXARGS@|\'${cross_cxxflags// /\',\'}\'|g" \
-e "s|@LDARGS@|\'${cross_ldflags// /\',\'}\'|g"
}
build() {
meson setup vkd3d-proton "build/x64" \
--prefix "/usr/share/vkd3d-proton/x64" \
--cross-file vkd3d-proton/build-win64.txt \
--bindir "" --libdir "" \
--buildtype "plain" \
-Denable_tests=false \
-Db_ndebug=false \
--strip
ninja -C "build/x64" -v
meson setup vkd3d-proton "build/x86" \
--cross-file vkd3d-proton/build-win32.txt \
--prefix "/usr/share/vkd3d-proton/x86" \
--bindir "" --libdir "" \
--buildtype "plain" \
-Denable_tests=false \
-Db_ndebug=false \
--strip
ninja -C "build/x86" -v
}
package() {
depends=('vulkan-icd-loader' 'lib32-vulkan-icd-loader' 'wine' 'bash')
DESTDIR="$pkgdir" ninja -C "build/x86" install
DESTDIR="$pkgdir" ninja -C "build/x64" install
install -Dm 755 -t "$pkgdir/usr/share/vkd3d-proton" setup_vkd3d_proton.sh
install -Dm 644 -t "$pkgdir/usr/share/doc/$pkgname" vkd3d-proton/README.md
install -Dm 644 -t "$pkgdir/usr/share/licenses/$pkgname" vkd3d-proton/LICENSE
install -Dm 755 -t "$pkgdir/usr/bin" setup_vkd3d_proton
}
sha256sums=('2b45dced482fa02f26ffac3d1e450b0ed4e5b81415c18337a4db38bce3b08938'
'bcc15521e4c7f966a0192a1dabb7fb4935b33db39344ab5b861f9d81486f1362'
'5a72af2395f7bc700d566add343b8742ebd6facc0d682f1386be44cce1d19c5b'
'67815eed9d47bbf610e23c6a1e4954c11371886c2ca73555dd9f1d6fbebb1323')
|