blob: 8cd767a407e1e7dec23e6dad2e373b7243600b20 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: vielfrass
# Maintainer: Jef Roosens
# Contributor: Logan Magee <mageelog@gmail.com>
# Commit hashes for the latest release in the v & vc repositories
# Using the direct downloads for the commits greatly reduces the time needed to
# pull down the sources, as the vlang repository is >100MB.
_v_commit_sha=9b1937a87166e3327497f332bf9584ff90592617
_vc_commit_sha=27942c7ab5a12b9253eb69eaf3a58699bcdd5189
pkgname=vlang
pkgver=0.4.10
pkgrel=2
pkgdesc='Simple, fast, safe, compiled language for developing maintainable software'
arch=('x86_64' 'aarch64')
url='https://vlang.io'
license=('MIT')
depends=('glibc')
optdepends=('glfw: Needed for graphics support'
'freetype2: Needed for graphics support'
'openssl: Needed for http support')
makedepends=('git' 'libx11')
conflicts=('v')
source=("v-${pkgver}.zip::https://github.com/vlang/v/archive/${_v_commit_sha}.zip"
"vc-${pkgver}.zip::https://github.com/vlang/vc/archive/${_vc_commit_sha}.zip")
sha256sums=('8ac80fd79f80ea7aa1b244d2b3e0d2f12f97b32b71c5823704b5dd6134818239'
'bd2c0515a81e71f511ed62ce9ae90378c368d236bee086262fb10b7366cf85fa')
sha512sums=('993bf3d65e092f7eb51b128ec15f9b4a78c28356e9f68981c3c2df913f2b1706dcf24f5411909f3b6a2e96c22dd88d1da236b5a0250aa3e208d836dd56c6d1b0'
'af8aa7280e93010f10966e99be7879e26afdf7a54ae5013f171953be941357f68b1142a01d11d6d156547f454e7c1e03e0e13fab6121aeb12ed27dcb8371a480')
prepare() {
# In case the previous directory still exists
rm -rf "v-${_v_commit_sha}/vc"
mv "vc-${_vc_commit_sha}" "v-${_v_commit_sha}/vc"
# We have to set local=1 because we manually download a specific vc
# version. This flag also disables downloading tcc, so we do that
# beforehand.
make -C "v-${_v_commit_sha}" fresh_tcc
}
build() {
cd "v-${_v_commit_sha}"
local tmpdir="/tmp/${pkgname}-${_v_commit_sha}"
mkdir -p "$tmpdir" || { echo "Can't create temporary directory!"; exit 1; }
# Delete directory when exiting function (even if there is an error)
trap 'rm -rf "$tmpdir"' RETURN
# Redefining HOME and TMPDIR for Isolation
export HOME="$tmpdir"
export TMPDIR="$tmpdir"
CFLAGS="" LDFLAGS="" make prod=1 local=1
# Compile all tools
LDFLAGS='' ./v build-tools
}
package() {
cd "v-${_v_commit_sha}"
install -d "${pkgdir}/usr/lib/vlang" "${pkgdir}/usr/share/vlang" "${pkgdir}/usr/bin"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm755 v "${pkgdir}/usr/lib/vlang"
cp -a cmd "${pkgdir}/usr/lib/vlang/"
cp -a examples "${pkgdir}/usr/share/vlang/"
cp -a thirdparty "${pkgdir}/usr/lib/vlang/"
cp -a vlib "${pkgdir}/usr/lib/vlang/"
cp v.mod "${pkgdir}/usr/lib/vlang/"
ln -s /usr/lib/vlang/v "${pkgdir}/usr/bin/v"
touch "${pkgdir}/usr/lib/vlang/cmd/tools/.disable_autorecompilation"
}
# vim: ft=bash
|