blob: 8fc40b81af9b80857ef18f3102593b3ae0172faa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
pkgname=('vulkan-caps-viewer-x11' 'vulkan-caps-viewer-wayland')
pkgbase=vulkan-caps-viewer
pkgver=4.00
pkgrel=1
epoch=1
pkgdesc="Vulkan Hardware Capability Viewer"
arch=('x86_64' 'aarch64')
url="https://vulkan.gpuinfo.org"
license=('LGPL-3.0-or-later')
makedepends=('git' 'qt5-wayland' 'qt5-x11extras' 'vulkan-icd-loader')
source=("git+https://github.com/SaschaWillems/VulkanCapsViewer.git#tag=$pkgver"
'git+https://github.com/KhronosGroup/Vulkan-Headers.git')
sha256sums=('440f8fd9545ff53ca7f949b55b3514c55d7f9fb21243aab83a1ba16d781c7b4a'
'SKIP')
prepare() {
# Create build directories
mkdir -p build-x11 build-wayland
cd VulkanCapsViewer
git submodule init
git config submodule.Vulkan-Headers.url "$srcdir/Vulkan-Headers"
git -c protocol.file.allow=always submodule update
}
build() {
# X11
pushd build-x11
qmake-qt5 ../VulkanCapsViewer \
DEFINES+=X11 \
CONFIG+=release \
PREFIX=/usr
make
popd
# Wayland
pushd build-wayland
qmake-qt5 ../VulkanCapsViewer \
DEFINES+=WAYLAND \
CONFIG+=release \
PREFIX=/usr
make
popd
}
package_vulkan-caps-viewer-x11() {
pkgdesc+=" (X11)"
depends=('hicolor-icon-theme' 'qt5-x11extras' 'vulkan-icd-loader')
provides=('vulkan-caps-viewer')
conflicts=('vulkan-caps-viewer')
cd build-x11
make INSTALL_ROOT="$pkgdir/" install
install -m644 ../VulkanCapsViewer/gfx/android_icon_256.png \
"$pkgdir"/usr/share/icons/hicolor/256x256/apps/vulkanCapsViewer.png
}
package_vulkan-caps-viewer-wayland() {
pkgdesc+=" (Wayland)"
depends=('hicolor-icon-theme' 'qt5-wayland' 'vulkan-icd-loader')
provides=('vulkan-caps-viewer')
conflicts=('vulkan-caps-viewer')
cd build-wayland
make INSTALL_ROOT="$pkgdir/" install
install -m644 ../VulkanCapsViewer/gfx/android_icon_256.png \
"$pkgdir"/usr/share/icons/hicolor/256x256/apps/vulkanCapsViewer.png
}
|