blob: 6fff7b179cdaa105a00697cf581306e84e346531 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Mario Finelli <mario at finel dot li>
pkgname=wgo
pkgver=0.5.7
pkgrel=1
pkgdesc="Live reload for Go apps"
arch=(x86_64)
url=https://github.com/bokwoon95/wgo
license=(MIT)
depends=(glibc)
makedepends=(go)
source=(${url}/archive/v${pkgver}/$pkgname-$pkgver.tar.gz)
sha256sums=('49bd5e622f04adea77d94eebfaf47934a2bde7b3bb863733d2bab28eeebcd7dd')
prepare() {
cd $pkgname-$pkgver
export GOPATH="${srcdir}/gopath"
go mod download
}
build() {
cd $pkgname-$pkgver
export CGO_LDFLAGS="$LDFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export GOPATH="${srcdir}/gopath"
go build \
-o wgo \
-trimpath \
-buildmode=pie \
-mod=readonly \
-ldflags "-linkmode external -extldflags \"${LDFLAGS}\"" \
./...
}
check() {
cd $pkgname-$pkgver
export GOPATH="$srcdir/gopath"
go test -mod=readonly -v ./...
}
package() {
cd $pkgname-$pkgver
install -Dm0755 wgo "$pkgdir/usr/bin/wgo"
install -vDm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim: set ts=2 sw=2 et:
|