blob: 2d8f095310ef25d7527d5c234cd5ea22be53496d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: robertfoster
_pkgbase=whisper.cpp
pkgname="${_pkgbase}-cuda"
pkgver=1.7.5 # renovate: datasource=github-tags depName=ggerganov/whisper.cpp
pkgrel=4
pkgdesc="Port of OpenAI's Whisper model in C/C++ (with NVIDIA CUDA optimizations)"
arch=('armv7h' 'aarch64' 'x86_64')
url="https://github.com/ggerganov/whisper.cpp"
license=("MIT")
depends=('ggml-cublas-git' 'sdl2-compat')
conflicts=("${_pkgbase}")
provides=("${_pkgbase}")
makedepends=(
'cmake'
'git'
)
source=("${_pkgbase}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
build() {
cmake \
-B "${srcdir}/build" \
-S "${srcdir}/${_pkgbase}-${pkgver}" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_CUDA_ARCHITECTURES=89-real \
-DWHISPER_SDL2=1 \
-DWHISPER_USE_SYSTEM_GGML=1
cmake --build "${srcdir}/build"
}
package() {
DESTDIR="${pkgdir}" cmake --install "${srcdir}/build"
cd "${srcdir}/build/bin"
for i in whisper-*; do
install -Dm755 "${i}" \
"${pkgdir}/usr/bin/${i}"
done
install -Dm644 "${srcdir}/${_pkgbase}-${pkgver}/LICENSE" \
-t "${pkgdir}/usr/share/licenses/${pkgname}"
}
sha256sums=('2fda42b57b7b8427d724551bd041616d85401fb9382e42b0349132a28920a34f')
|