blob: 045779e3ff57e3d6ce0785011ef1e7c46c67848e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: a821 at (nospam) mail de
# Contributor: David Runge <dvzrv@archlinux.org>
# Contributor: Maxime Vincent <maxime.vince@gmail.com>
pkgname=wolfssl-git
pkgver=5.7.6.r280.gdb0fa304a
pkgrel=1
pkgdesc='Lightweight, portable, C-language-based SSL/TLS library'
arch=('x86_64')
license=('GPL-2.0-or-later')
depends=('glibc')
makedepends=('cmake' 'git')
url='https://www.wolfssl.com/'
source=(git+https://github.com/wolfSSL/wolfssl.git)
sha256sums=('SKIP')
provides=("${pkgname%-git}" "libwolfssl.so")
conflicts=("${pkgname%-git}")
pkgver() {
cd wolfssl
git describe --long --tags | sed 's/^v//;s/-stable//;s/-/.r/;s/-/./g'
}
build() {
cmake -B build -S wolfssl \
-D CMAKE_BUILD_TYPE=None \
-D CMAKE_INSTALL_PREFIX=/usr \
-D WOLFSSL_CURVE25519=ON \
-D WOLFSSL_CURVE448=ON \
-D WOLFSSL_ED25519=ON \
-D WOLFSSL_ED448=ON \
-D WOLFSSL_REPRODUCIBLE_BUILD=ON \
-D WOLFSSL_SNI=ON \
-D WARNING_C_FLAGS="$CFLAGS" \
-W no-dev
cmake --build build
}
check() {
./build/wolfcrypt/test/testwolfcrypt
}
package() {
DESTDIR="$pkgdir" cmake --install build
install -Dm644 wolfssl/{README,ChangeLog}.md -t "$pkgdir/usr/share/doc/wolfssl"
}
|