blob: 1571205146bef6b9c81bd291e957a13e0baf365f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: Eugene Gershnik <gershnik@hotmail.com>
pkgname='wsdd-native'
pkgver='1.18'
pkgrel=1
pkgdesc='WS-Discovery Host Daemon. Makes your machine visible in Network view of Windows Explorer'
arch=('x86_64' 'aarch64')
url='https://github.com/gershnik/wsdd-native'
license=('BSD-3-Clause')
depends=('glibc' 'gcc-libs')
makedepends=('cmake>=3.25' 'make' 'gcc>=11.3' 'git' 'patch' 'libsystemd')
conflicts=('wsdd')
backup=('etc/wsddn.conf')
source=("$pkgname-$pkgver.tar.gz::https://github.com/gershnik/wsdd-native/archive/v$pkgver.tar.gz")
sha256sums=('abd317486ad82cf2bf0c284f41a815a88227fdc9cceac6cbc8035ea28c470e86')
build() {
cd "$pkgname-$pkgver"
cmake -S . -B out -DCMAKE_BUILD_TYPE=None
cmake --build out
cp installers/wsddn.conf out/
sed -i "s/{RELOAD_INSTRUCTIONS}/# sudo systemctl restart wsddn\n/g" out/wsddn.conf
sed -i "s/{SAMPLE_IFACE_NAME}/eth0/g" out/wsddn.conf
}
package() {
cd "$pkgname-$pkgver"
cmake --install out --prefix $pkgdir/usr
install -Dm 0644 config/systemd/usr/lib/systemd/system/wsddn.service \
$pkgdir/usr/lib/systemd/system/wsddn.service
install -Dm 0644 config/firewalls/etc/ufw/applications.d/wsddn \
$pkgdir/etc/ufw/applications.d/wsddn
install -Dm 0644 out/wsddn.conf $pkgdir/etc/wsddn.conf
install -Dm 0644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
}
|