PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer: Ícar N. S. <icar.nin@protonmail.com>
pkgname=xnine-git
pkgver=r45.4f38fd5
pkgrel=3
pkgdesc="Native Direct3D9 driver for DXVK-Native games."
arch=(x86_64)
url="https://github.com/zmike/Xnine"
license=('MIT')
makedepends=('git' 'make' 'gcc')
depends=(
    'mesa'
    'lib32-mesa'
    'sdl2'
    'lib32-sdl2'
    'libx11'
    'lib32-libx11'
    'libxcb'
    'lib32-libxcb'
    'libxext'
    'lib32-libxext'
    'glibc'
    'lib32-glibc'
    'libxau'
    'lib32-libxau'
    'libxdmcp'
    'lib32-libxdmcp'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("Xnine::git+$url#branch=master" build-fix.patch)
md5sums=('SKIP'
         'd19f019a8dc90fa3d9eca6972ca8cada')

prepare() {
    cd Xnine
    patch -Np1 -i ../build-fix.patch
}

pkgver() {
    cd Xnine
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd Xnine
    ./build.sh
}

package() {
    cd Xnine
    mkdir -p "$pkgdir/usr/share/Xnine/"
    install -Dm755 nine_sdl.so "$pkgdir/usr/share/Xnine/"
    install -Dm755 nine_sdl64.so "$pkgdir/usr/share/Xnine/"
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/Xnine/LICENSE"
}