blob: 4c2b185ffbb758067f23aa0dabdfd72f8bea5eac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# vim:ts=2:sw=2:expandtab
# Maintainer: peelz <peelz.dev+arch@gmail.com>
pkgname="xrizer-git"
pkgver="0.1.r20.g4fbcfc6"
pkgrel="1"
pkgdesc="Reimplementation of OpenVR, translating calls to OpenXR."
arch=("x86_64")
url="https://github.com/Supreeeme/xrizer"
license=("GPL-3.0-or-later")
depends=(
"glibc"
"gcc-libs"
)
makedepends=(
"git"
"rust"
"cmake"
"libx11"
"libxcb"
"wayland"
"clang"
"shaderc"
)
provides=("xrizer")
conflicts=("xrizer")
source=(
"${pkgname}::git+${url}.git"
)
sha256sums=(
"SKIP"
)
options=("!lto")
pkgver() {
cd "${srcdir}/${pkgname}"
git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/${pkgname}"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "${srcdir}/${pkgname}"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
package() {
cd "${srcdir}/${pkgname}"
install -Dm755 \
"${srcdir}/${pkgname}/target/release/libxrizer.so" \
"${pkgdir}/opt/xrizer/bin/linux64/vrclient.so"
}
|