Package Details: qrookie-vrp 0.4.2-1

Git Clone URL: https://aur.archlinux.org/qrookie-vrp.git (read-only, click to copy)
Package Base: qrookie-vrp
Description: Download and install Quest games from ROOKIE Public Mirror
Upstream URL: https://github.com/glaumar/QRookie
Keywords: metaquest oculus quest vr xr
Licenses: GPL-3.0-or-later
Provides: QRookie
Submitter: glaumar
Maintainer: glaumar (robertfoster)
Last Packager: glaumar
Votes: 2
Popularity: 0.155310
First Submitted: 2024-03-29 12:25 (UTC)
Last Updated: 2025-01-21 15:01 (UTC)

Latest Comments

glaumar commented on 2025-01-20 16:43 (UTC)

I have added you to the list of co-maintainers of qrookie-vrp @robertfoster

robertfoster commented on 2025-01-20 11:37 (UTC) 

pkgname=qrookie-vrp
pkgver=0.4.2
pkgrel=1
pkgdesc='Download and install Quest games from ROOKIE Public Mirror'
arch=('x86_64')
url='https://github.com/glaumar/QRookie'
license=(GPL-3.0-or-later)
depends=(hicolor-icon-theme
  qt6-base
  qt6-declarative
  gcc-libs
  qcoro-qt6
  kirigami
  qqc2-breeze-style
  xdg-utils
  p7zip
  android-tools
  android-sdk-build-tools
  android-apktool
)
makedepends=(cmake extra-cmake-modules)
provides=(QRookie)
source=(
  "https://github.com/glaumar/QRookie/archive/refs/tags/v${pkgver}.tar.gz"
)

sha256sums=('e837e63a357c5ba08378fc5459ef966cc0617036e90ef2cf8717424a017c53c5')

build() {
  cmake -B build -S "QRookie-${pkgver}" -DCMAKE_BUILD_TYPE='Release' -DCMAKE_INSTALL_PREFIX='/usr'
  cmake --build build --target QRookie
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}

robertfoster commented on 2025-01-09 11:34 (UTC) 

# Maintainer: Glaumar git@geekgo.tech

pkgname=qrookie-vrp
pkgver=0.4.1
pkgrel=1
pkgdesc='Download and install Quest games from ROOKIE Public Mirror'
arch=('x86_64')
url='https://github.com/glaumar/QRookie'
license=(GPL-3.0-or-later)
depends=(hicolor-icon-theme
  qt6-base
  qt6-declarative
  gcc-libs
  qcoro-qt6
  kirigami
  qqc2-breeze-style
  xdg-utils
  p7zip
  android-tools
  android-sdk-build-tools
  android-apktool
)
makedepends=(cmake extra-cmake-modules)
provides=(QRookie)
source=(
  "https://github.com/glaumar/QRookie/archive/refs/tags/v${pkgver}.tar.gz"
  https://github.com/glaumar/QRookie/commit/49b0f55ac03af890e227b1524762bcf8daec95a1.patch
  https://github.com/glaumar/QRookie/commit/0cd035c276d03fa0f0926947ebef86a1eb005672.patch
)

sha256sums=('1e1877600c5719657a2ff68e35d7870ea96759045f6348c0fd31964169b79cfb'
  '918fb4ab0c09aef75236259f56d8396712203aa4e81a2d7fd7bf43b051359175'
  'badf6ea866ba53b264480b29a9d18273a5d78319695eeb36e0421cca03ec53b1')

prepare() {
  cd "QRookie-${pkgver}"
  patch -Np1 -i ../49b0f55ac03af890e227b1524762bcf8daec95a1.patch
  patch -Np1 -i ../0cd035c276d03fa0f0926947ebef86a1eb005672.patch
}
build() {
  cmake -B build -S "QRookie-${pkgver}" -DCMAKE_BUILD_TYPE='Release' -DCMAKE_INSTALL_PREFIX='/usr'
  cmake --build build --target QRookie
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}

ngoonee commented on 2024-10-19 00:42 (UTC)

Updating to 0.4.1 works fine with just updating the pkgver and checksum.