Package Details: virt-install-git 4.1.0.r323.gb83a1b0d0-1

Git Clone URL: https://aur.archlinux.org/virt-manager-git.git (read-only, click to copy)
Package Base: virt-manager-git
Description: Console user interface for managing virtual machines
Upstream URL: http://virt-manager.org/
Keywords: libvirt virtualization
Licenses: GPL
Conflicts: virt-install
Provides: virt-install
Submitter: unknown
Maintainer: z3ntu
Last Packager: z3ntu
Votes: 16
Popularity: 0.94
First Submitted: 2011-04-08 14:26 (UTC)
Last Updated: 2024-09-22 18:09 (UTC)

Latest Comments

1 2 3 4 Next › Last »

MaximGun commented on 2024-11-14 14:31 (UTC) (edited on 2024-11-14 14:38 (UTC) by MaximGun)

I updated PKGBUILD for meson. Remove -Dtests=disabled if you want to run tests, but it requires more makedepends.

_pkgbase=virt-manager
pkgbase=$_pkgbase-git
pkgname=(virt-install-git virt-manager-git)
pkgver=4.1.0.r447.gd93e3cb8d
pkgrel=1
pkgdesc="Console user interface for managing virtual machines"
arch=('any')
url="http://virt-manager.org/"
license=('GPL')
depends=('python-gobject' 'libvirt-glib' 'libvirt-python'
    'python-requests' 'libosinfo' 'python-tqdm')
makedepends=('git' 'meson' 'ninja' 'python-cairo' 'python-docutils')
source=("git+https://github.com/virt-manager/virt-manager.git")
sha512sums=('SKIP')

pkgver() {
    cd "$srcdir/$_pkgbase"
    git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "$srcdir/$_pkgbase"
    meson setup build --prefix=/usr --buildtype=release -Dtests=disabled
    meson compile -C build
}

package_virt-install-git() {
    provides=('virt-install')
    conflicts=('virt-install')
    cd "$srcdir/$_pkgbase/build"
    DESTDIR="$pkgdir" meson install
    python -m compileall "${pkgdir}/usr/share/virt-manager"
    python -O -m compileall "${pkgdir}/usr/share/virt-manager"
    rm "${pkgdir}/usr/bin/virt-manager"
}

package_virt-manager-git() {
    pkgdesc="Desktop user interface for managing virtual machines"
    depends=("virt-install-git=$pkgver" 'vte3' 'gtk-vnc' 'spice-gtk' 'python-cairo')
    provides=('virt-manager')
    conflicts=('virt-manager')
    cd "$srcdir/$_pkgbase/build"
    install -Dm 755 virt-manager -t "${pkgdir}/usr/bin"
}

taoky commented on 2024-11-13 05:32 (UTC)

virt-manager now uses meson instead of setuptools, and the PKGBUILD is now broken.

taoky commented on 2024-09-16 11:08 (UTC)

spice-gtk3 shall be updated to spice-gtk to support spice-gtk-git in AUR.

Sonotsugipaa commented on 2021-07-15 21:14 (UTC)

I think gtksourceview4 needs to be added as a dependency, since after a system upgrade/cleanup trying to open a VM an error would read: Namespace GtkSource not available.

C0rn3j commented on 2021-05-27 11:28 (UTC)

Needs a dependency on python-tqdm it seems.

profiluefter commented on 2020-09-14 12:00 (UTC)

Should have a dependency on python-docutils

maikoool commented on 2016-03-24 17:38 (UTC) (edited on 2016-03-24 17:38 (UTC) by maikoool)

Installing these packages I am presented with an error: virt-install-git: /usr/share/glib-2.0/schemas/gschemas.compiled exists in filesystem virt-install-git: /usr/share/icons/hicolor/icon-theme.cache exists in filesystem Are these files supposed to be packaged?

1 2 3 4 Next › Last »